home *** CD-ROM | disk | FTP | other *** search
/ TeX 1995 July / TeX CD-ROM July 1995 (Disc 1)(Walnut Creek)(1995).ISO / biblio / bibtex / contrib / germbib / bst / gerabbrv.bst < prev    next >
Text File  |  1993-04-20  |  24KB  |  1,206 lines
  1. % BibTeX standard bibliography style `abbrv'
  2.         % version 0.99a for BibTeX versions 0.99a or later, LaTeX version 2.09.
  3.         % Copyright (C) 1985, all rights reserved.
  4.         % Copying of this file is authorized only if either
  5.         % (1) you make absolutely no changes to your copy, including name, or
  6.         % (2) if you do make changes, you name it something other than
  7.         % btxbst.doc, plain.bst, unsrt.bst, alpha.bst, and abbrv.bst.
  8.         % This restriction helps ensure that all standard styles are identical.
  9.         % The file btxbst.doc has the documentation for this style.
  10. %   15-feb-92   (MW)    Updated for use with `bibgerman.sty': things like "and"
  11. %                       change with the language. Switch the language using the
  12. %                       language field: 
  13. %                          language = "german" | "USenglish" | "english"
  14. %                       Then a `\selectlanguage{...}' command will be pushed just
  15. %                       before the `\bibitem...' command for the entry in work.
  16.  
  17.  
  18. ENTRY
  19.   { address
  20.     author
  21.     booktitle
  22.     chapter
  23.     edition
  24.     editor
  25.     howpublished
  26.     institution
  27.     journal
  28.     key
  29.     language
  30.     month
  31.     note
  32.     number
  33.     organization
  34.     pages
  35.     publisher
  36.     school
  37.     series
  38.     title
  39.     type
  40.     volume
  41.     year
  42.   }
  43.   {}
  44.   { label }
  45.  
  46. INTEGERS { output.state before.all mid.sentence after.sentence after.block before.title }
  47.  
  48. STRINGS { s t language.state language.temp }
  49.  
  50. FUNCTION {init.state.consts}
  51. { #0 'before.all :=
  52.   #1 'mid.sentence :=
  53.   #2 'after.sentence :=
  54.   #3 'after.block :=
  55.   #4 'before.title :=
  56.   "nostate" 'language.state :=
  57. }
  58.  
  59. FUNCTION {language.state.test}
  60. { 
  61.   'language.temp :=
  62.   language.temp language.state =
  63.     { #1 }
  64.     { #0 }
  65.   if$
  66. }
  67.  
  68. FUNCTION {not}
  69. {   { #0 }
  70.     { #1 }
  71.   if$
  72. }
  73.  
  74. FUNCTION {and}
  75. {   'skip$
  76.     { pop$ #0 }
  77.   if$
  78. }
  79.  
  80. FUNCTION {or}
  81. {   { pop$ #1 }
  82.     'skip$
  83.   if$
  84. }
  85.  
  86. FUNCTION {output.nonnull}
  87. { 's :=
  88.   output.state mid.sentence =
  89.     { ", " * write$ }
  90.     { output.state after.block =
  91.         { add.period$ write$
  92.           newline$
  93.           "\newblock " write$
  94.         }
  95.         { output.state before.all =
  96.             'write$
  97.             % next if is for use with `new' FUNCTION {after.authors}
  98.             { output.state before.title =
  99.                 { ": " * write$ }
  100.                 { add.period$ " " * write$ }
  101.               if$
  102.             }
  103.           if$
  104.         }
  105.       if$
  106.       mid.sentence 'output.state :=
  107.     }
  108.   if$
  109.   s
  110. }
  111.  
  112. FUNCTION {output}
  113. { duplicate$ empty$
  114.     'pop$
  115.     'output.nonnull
  116.   if$
  117. }
  118.  
  119. FUNCTION {output.check}
  120. { 't :=
  121.   duplicate$ empty$
  122.     { pop$ "empty " t * " in " * cite$ * warning$ }
  123.     'output.nonnull
  124.   if$
  125. }
  126.  
  127. FUNCTION {output.bibitem}
  128. { newline$
  129.   language empty$
  130.     'skip$
  131.     { language.state language =
  132.         'skip$
  133.         { "\selectlanguage{\" language * "}" * write$
  134.           newline$
  135.         }
  136.       if$
  137.       language 'language.state :=
  138.     }
  139.   if$
  140.   "\bibitem{" write$
  141.   cite$ write$
  142.   "}" write$
  143.   newline$
  144.   ""
  145.   before.all 'output.state :=
  146. }
  147.  
  148. FUNCTION {fin.entry}
  149. { add.period$
  150.   write$
  151.   newline$
  152. }
  153.  
  154. FUNCTION {new.block}
  155. { output.state before.all =
  156.     'skip$
  157.     { after.block 'output.state := }
  158.   if$
  159. }
  160.  
  161. FUNCTION {new.sentence}
  162. { output.state after.block =
  163.     'skip$
  164.     { output.state before.all =
  165.         'skip$
  166.         { after.sentence 'output.state := }
  167.       if$
  168.     }
  169.   if$
  170. }
  171.  
  172. % new one -> sets what is specified in FUNCTION {output.nonnull}
  173. % if `before.title 'output.state = ... if$' is true
  174. FUNCTION {after.authors}
  175. { output.state before.all =
  176.     'skip$
  177.     { before.title 'output.state := }
  178.   if$
  179. }
  180.  
  181. FUNCTION {new.block.checka}
  182. { empty$
  183.     'skip$
  184.     'new.block
  185.   if$
  186. }
  187.  
  188. FUNCTION {new.block.checkb}
  189. { empty$
  190.   swap$ empty$
  191.   and
  192.     'skip$
  193.     'new.block
  194.   if$
  195. }
  196.  
  197. FUNCTION {new.block.checkc}
  198. { empty$
  199.   swap$ empty$
  200.   and
  201.     'skip$
  202.     'after.authors
  203.   if$
  204. }
  205.  
  206. FUNCTION {new.sentence.checka}
  207. { empty$
  208.     'skip$
  209.     'new.sentence
  210.   if$
  211. }
  212.  
  213. FUNCTION {new.sentence.checkb}
  214. { empty$
  215.   swap$ empty$
  216.   and
  217.     'skip$
  218.     'new.sentence
  219.   if$
  220. }
  221.  
  222. FUNCTION {field.or.null}
  223. { duplicate$ empty$
  224.     { pop$ "" }
  225.     'skip$
  226.   if$
  227. }
  228.  
  229. FUNCTION {emphasize}
  230. { duplicate$ empty$
  231.     { pop$ "" }
  232.     { "{\em " swap$ * "\/}" * }
  233.   if$
  234. }
  235.  
  236. FUNCTION {smallcaps}
  237. { duplicate$ empty$
  238.     { pop$ "" }
  239.     { "{\sc " swap$ * "}" * }
  240.   if$
  241. }
  242.  
  243. INTEGERS { nameptr namesleft numnames }
  244.  
  245. FUNCTION {format.names}
  246. { 's :=
  247.   #1 'nameptr :=
  248.   s num.names$ 'numnames :=
  249.   numnames 'namesleft :=
  250.     { namesleft #0 > }
  251.     { nameptr #1 >
  252.         { s nameptr "{f.~}{vv~}{ll}{, jj}" format.name$ smallcaps 't :=
  253.           namesleft #1 >
  254.             { ", " * t * }
  255.             { numnames #2 >
  256.                 { "english" language.state.test
  257.                   "USenglish" language.state.test
  258.                   or
  259.                      {"," * }
  260.                      'skip$
  261.                   if$
  262.                 }
  263.                 'skip$
  264.               if$
  265.               t "others" =
  266.                 { " \btxetalshort{.}" * }
  267.                 { " \btxandshort{.}\ " * t * }
  268.               if$
  269.             }
  270.           if$
  271.         }
  272.         { s nameptr "{ll}{, jj}{, f.}{~vv}" format.name$ smallcaps }
  273.       if$
  274.       nameptr #1 + 'nameptr :=
  275.       namesleft #1 - 'namesleft :=
  276.     }
  277.   while$
  278. }
  279.  
  280. FUNCTION {format.authors}
  281. { author empty$
  282.     { "" }
  283.     { author format.names }
  284.   if$
  285. }
  286.  
  287. FUNCTION {format.editors}
  288. { editor empty$
  289.     { "" }
  290.     { editor format.names
  291.       editor num.names$ #1 >
  292.         { "\ (\btxeditorsshort{.})" * }
  293.         { "\ (\btxeditorshort{.})" * }
  294.       if$
  295.     }
  296.   if$
  297. }
  298.  
  299. FUNCTION {format.title}
  300. { title empty$
  301.     { "" }
  302.     { "english" language.state.test
  303.       "USenglish" language.state.test
  304.       or
  305.         { title "t" change.case$ emphasize }
  306.         { title emphasize }
  307.       if$
  308.     }
  309.   if$
  310. }
  311.  
  312. FUNCTION {n.dashify}
  313. { 't :=
  314.   ""
  315.     { t empty$ not }
  316.     { t #1 #1 substring$ "-" =
  317.         { t #1 #2 substring$ "--" = not
  318.             { "--" *
  319.               t #2 global.max$ substring$ 't :=
  320.             }
  321.             {   { t #1 #1 substring$ "-" = }
  322.                 { "-" *
  323.                   t #2 global.max$ substring$ 't :=
  324.                 }
  325.               while$
  326.             }
  327.           if$
  328.         }
  329.         { t #1 #1 substring$ *
  330.           t #2 global.max$ substring$ 't :=
  331.         }
  332.       if$
  333.     }
  334.   while$
  335. }
  336.  
  337. FUNCTION {format.date}
  338. { year empty$
  339.     { month empty$
  340.         { "" }
  341.         { "there's a month but no year in " cite$ * warning$
  342.           month
  343.         }
  344.       if$
  345.     }
  346.     { month empty$
  347.         'year
  348.         { month "\ " * year * }
  349.       if$
  350.     }
  351.   if$
  352. }
  353.  
  354. FUNCTION {format.btitle}
  355. { title emphasize
  356. }
  357.  
  358. FUNCTION {tie.or.space.connect}
  359. { duplicate$ text.length$ #3 <
  360.     { "~" }
  361.     { "\ " }
  362.   if$
  363.   swap$ * *
  364. }
  365.  
  366. FUNCTION {either.or.check}
  367. { empty$
  368.     'pop$
  369.     { "can't use both " swap$ * " fields in " * cite$ * warning$ }
  370.   if$
  371. }
  372.  
  373. FUNCTION {format.bvolume}
  374. { volume empty$
  375.     { "" }
  376.     { output.state after.block =
  377.         { "\Btxvolumeshort{.}" }
  378.         { "\btxvolumeshort{.}" }
  379.       if$
  380.       volume tie.or.space.connect
  381.       series empty$
  382.         'skip$
  383.         { " \btxofseriesshort{.}\ " * series emphasize * }
  384.       if$
  385.       "volume and number" number either.or.check
  386.     }
  387.   if$
  388. }
  389.  
  390. FUNCTION {format.number.series}
  391. { volume empty$
  392.     { number empty$
  393.         { series field.or.null }
  394.         { output.state mid.sentence =
  395.             { "\btxnumbershort{.}" }
  396.             { "\Btxnumbershort{.}" }
  397.           if$
  398.           number tie.or.space.connect
  399.           series empty$
  400.             { "there's a number but no series in " cite$ * warning$ }
  401.             { " \btxinseriesshort{.}\ " * series emphasize * }
  402.           if$
  403.         }
  404.       if$
  405.     }
  406.     { "" }
  407.   if$
  408. }
  409.  
  410. FUNCTION {format.edition}
  411. { edition empty$
  412.     { "" }
  413.     { "english" language.state.test
  414.       "USenglish" language.state.test
  415.       or
  416.         { output.state mid.sentence =
  417.             { edition "l" change.case$ " \btxeditionshort{.}" * }
  418.             { edition "t" change.case$ " \btxeditionshort{.}" * }
  419.           if$
  420.         }
  421.         { edition " \btxeditionshort{.}" * }
  422.       if$
  423.     }
  424.   if$
  425. }
  426.  
  427. INTEGERS { multiresult }
  428.  
  429. FUNCTION {multi.page.check}
  430. { 't :=
  431.   #0 'multiresult :=
  432.     { multiresult not
  433.       t empty$ not
  434.       and
  435.     }
  436.     { t #1 #1 substring$
  437.       duplicate$ "-" =
  438.       swap$ duplicate$ "," =
  439.       swap$ "+" =
  440.       or or
  441.         { #1 'multiresult := }
  442.         { t #2 global.max$ substring$ 't := }
  443.       if$
  444.     }
  445.   while$
  446.   multiresult
  447. }
  448.  
  449. FUNCTION {format.pages}
  450. { pages empty$
  451.     { "" }
  452.     { pages multi.page.check
  453.         { "\btxpagesshort{.}" pages n.dashify tie.or.space.connect }
  454.         { "\btxpageshort{.}" pages tie.or.space.connect }
  455.       if$
  456.     }
  457.   if$
  458. }
  459.  
  460. FUNCTION {format.vol.num.pages}
  461. { volume field.or.null
  462.   number empty$
  463.     'skip$
  464.     { "(" number * ")" * *
  465.       volume empty$
  466.         { "there's a number but no volume in " cite$ * warning$ }
  467.         'skip$
  468.       if$
  469.     }
  470.   if$
  471.   pages empty$
  472.     'skip$
  473.     { duplicate$ empty$
  474.         { pop$ format.pages }
  475.         { ":" * pages n.dashify * }
  476.       if$
  477.     }
  478.   if$
  479. }
  480.  
  481. FUNCTION {format.chapter.pages}
  482. { chapter empty$
  483.     'format.pages
  484.     { type empty$
  485.         { "\btxchaptershort{.}" }
  486.         { "english" language.state.test
  487.           "USenglish" language.state.test
  488.           or
  489.              { type "l" change.case$ }
  490.              { type }
  491.          if$
  492.         }
  493.       if$
  494.       chapter tie.or.space.connect
  495.       pages empty$
  496.         'skip$
  497.         { ", " * format.pages * }
  498.       if$
  499.     }
  500.   if$
  501. }
  502.  
  503. FUNCTION {format.in.ed.booktitle}
  504. { booktitle empty$
  505.     { "" }
  506.     { editor empty$
  507.         { "\Btxinshort{.}\ " booktitle emphasize * }
  508.         { "\Btxinshort{.}\ " format.editors * ": " * booktitle emphasize * }
  509.       if$
  510.     }
  511.   if$
  512. }
  513.  
  514. FUNCTION {empty.misc.check}
  515. { author empty$ title empty$ howpublished empty$
  516.   month empty$ year empty$ note empty$
  517.   and and and and and
  518.   key empty$ not and
  519.     { "all relevant fields are empty in " cite$ * warning$ }
  520.     'skip$
  521.   if$
  522. }
  523.  
  524. FUNCTION {format.thesis.type}
  525. { type empty$
  526.     'skip$
  527.     { pop$
  528.       "english" language.state.test
  529.       "USenglish" language.state.test
  530.       or
  531.         { type "t" change.case$ }
  532.         { type }
  533.       if$
  534.     }
  535.   if$
  536. }
  537.  
  538. FUNCTION {format.tr.number}
  539. { type empty$
  540.     { "\Btxtechrepshort{.}" }
  541.     'type
  542.   if$
  543.   number empty$
  544.     { "english" language.state.test
  545.       "USenglish" language.state.test
  546.       or
  547.         { type empty$
  548.             { pop$ "\btxtechreplong{}" }
  549.             { "t" change.case$ }
  550.           if$
  551.         }
  552.         'skip$
  553.       if$
  554.     }
  555.     { number tie.or.space.connect }
  556.   if$
  557. }
  558.  
  559. FUNCTION {format.article.crossref}
  560. { key empty$
  561.     { journal empty$
  562.         { "need key or journal for " cite$ * " to crossref " * crossref *
  563.           warning$
  564.           ""
  565.         }
  566.         { "\Btxinshort{.}\ " journal emphasize * }
  567.       if$
  568.     }
  569.     { "\Btxinshort{.}\ " key emphasize * }
  570.   if$
  571.   " \cite{" * crossref * "}" *
  572. }
  573.  
  574. FUNCTION {format.crossref.editor}
  575. { editor #1 "{ll}{, jj}{, f.}{~vv}" format.name$ smallcaps
  576.   editor num.names$ duplicate$
  577.   #2 >
  578.     { pop$ " \btxetalshort{.}" * }
  579.     { #2 <
  580.         'skip$
  581.         { editor #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
  582.             { " \btxetalshort{.}" * }
  583.             { " \btxandshort{.}\ " * editor #2 "{vv~}{ll}" format.name$ smallcaps * }
  584.           if$
  585.         }
  586.       if$
  587.     }
  588.   if$
  589. }
  590.  
  591. FUNCTION {format.book.crossref}
  592. { volume empty$
  593.     { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
  594.       "\Btxinshort{.}\ "
  595.     }
  596.     { "\Btxvolumeshort{.}" volume tie.or.space.connect
  597.       " \btxofseriesshort{.}\ " *
  598.     }
  599.   if$
  600.   editor empty$
  601.   editor field.or.null author field.or.null =
  602.   or
  603.     { key empty$
  604.         { series empty$
  605.             { "need editor, key, or series for " cite$ * " to crossref " *
  606.               crossref * warning$
  607.               "" *
  608.             }
  609.             { series emphasize * }
  610.           if$
  611.         }
  612.         { key emphasize * }
  613.       if$
  614.     }
  615.     { "\Btxinshort{.}\ " format.crossref.editor * }
  616.   if$
  617.   " \cite{" * crossref * "}" *
  618. }
  619.  
  620. FUNCTION {format.incoll.inproc.crossref}
  621. { editor empty$
  622.   editor field.or.null author field.or.null =
  623.   or
  624.     { key empty$
  625.         { booktitle empty$
  626.             { "need editor, key, or booktitle for " cite$ * " to crossref " *
  627.               crossref * warning$
  628.               ""
  629.             }
  630.             { "\Btxinshort{.}\ " booktitle emphasize * }
  631.           if$
  632.         }
  633.         { "\Btxinshort{.}\ " key emphasize * }
  634.       if$
  635.     }
  636.     { "\Btxinshort{.}\ " format.crossref.editor * }
  637.   if$
  638.   " \cite{" * crossref * "}" *
  639. }
  640.  
  641. FUNCTION {article}
  642. { output.bibitem
  643.   format.authors "author" output.check
  644.   after.authors
  645.   format.title "title" output.check
  646.   new.block
  647.   crossref missing$
  648.     { journal 
  649.       title missing$
  650.         { emphasize }
  651.         'skip$
  652.       if$
  653.       "journal" output.check 
  654.       format.vol.num.pages output
  655.       format.date "year" output.check
  656.     }
  657.     { format.article.crossref output.nonnull
  658.       format.pages output
  659.     }
  660.   if$
  661.   new.block
  662.   note output
  663.   fin.entry
  664. }
  665.  
  666. FUNCTION {book}
  667. { output.bibitem
  668.   author empty$
  669.     { format.editors "author and editor" output.check }
  670.     { format.authors output.nonnull
  671.       crossref missing$
  672.         { "author and editor" editor either.or.check }
  673.         'skip$
  674.       if$
  675.     }
  676.   if$
  677.   after.authors
  678.   format.btitle "title" output.check
  679.   crossref missing$
  680.     { format.bvolume output
  681.       new.block
  682.       format.number.series output
  683.       new.sentence
  684.       publisher "publisher" output.check
  685.       address output
  686.     }
  687.     { new.block
  688.       format.book.crossref output.nonnull
  689.     }
  690.   if$
  691.   format.edition output
  692.   format.date "year" output.check
  693.   new.block
  694.   note output
  695.   fin.entry
  696. }
  697.  
  698. FUNCTION {booklet}
  699. { output.bibitem
  700.   format.authors output
  701.   after.authors
  702.   format.title "title" output.check
  703.   howpublished address new.block.checkb
  704.   howpublished output
  705.   address output
  706.   format.date output
  707.   new.block
  708.   note output
  709.   fin.entry
  710. }
  711.  
  712. FUNCTION {inbook}
  713. { output.bibitem
  714.   author empty$
  715.     { format.editors "author and editor" output.check }
  716.     { format.authors output.nonnull
  717.       crossref missing$
  718.         { "author and editor" editor either.or.check }
  719.         'skip$
  720.       if$
  721.     }
  722.   if$
  723.   after.authors
  724.   format.btitle "title" output.check
  725.   crossref missing$
  726.     { format.bvolume output
  727.       format.chapter.pages "chapter and pages" output.check
  728.       new.block
  729.       format.number.series output
  730.       new.sentence
  731.       publisher "publisher" output.check
  732.       address output
  733.     }
  734.     { format.chapter.pages "chapter and pages" output.check
  735.       new.block
  736.       format.book.crossref output.nonnull
  737.     }
  738.   if$
  739.   format.edition output
  740.   format.date "year" output.check
  741.   new.block
  742.   note output
  743.   fin.entry
  744. }
  745.  
  746. FUNCTION {incollection}
  747. { output.bibitem
  748.   format.authors "author" output.check
  749.   after.authors
  750.   format.title "title" output.check
  751.   new.block
  752.   crossref missing$
  753.     { format.in.ed.booktitle "booktitle" output.check
  754.       format.bvolume output
  755.       format.number.series output
  756.       format.chapter.pages output
  757.       new.sentence
  758.       publisher "publisher" output.check
  759.       address output
  760.       format.edition output
  761.       format.date "year" output.check
  762.     }
  763.     { format.incoll.inproc.crossref output.nonnull
  764.       format.chapter.pages output
  765.     }
  766.   if$
  767.   new.block
  768.   note output
  769.   fin.entry
  770. }
  771.  
  772. FUNCTION {inproceedings}
  773. { output.bibitem
  774.   format.authors "author" output.check
  775.   after.authors
  776.   format.title "title" output.check
  777.   new.block
  778.   crossref missing$
  779.     { format.in.ed.booktitle "booktitle" output.check
  780.       format.bvolume output
  781.       format.number.series output
  782.       format.pages output
  783.       address empty$
  784.         { organization publisher new.sentence.checkb
  785.           organization output
  786.           publisher output
  787.           format.date "year" output.check
  788.         }
  789.         { address output.nonnull
  790.           format.date "year" output.check
  791.           new.sentence
  792.           organization output
  793.           publisher output
  794.         }
  795.       if$
  796.     }
  797.     { format.incoll.inproc.crossref output.nonnull
  798.       format.pages output
  799.     }
  800.   if$
  801.   new.block
  802.   note output
  803.   fin.entry
  804. }
  805.  
  806. FUNCTION {conference} { inproceedings }
  807.  
  808. FUNCTION {manual}
  809. { output.bibitem
  810.   author empty$
  811.     { organization empty$
  812.         'skip$
  813.         { organization smallcaps output.nonnull
  814.           address output
  815.         }
  816.       if$
  817.     }
  818.     { format.authors output.nonnull }
  819.   if$
  820.   after.authors
  821.   format.btitle "title" output.check
  822.   author empty$
  823.     { organization empty$
  824.         { address new.block.checka
  825.           address output
  826.         }
  827.         'skip$
  828.       if$
  829.     }
  830.     { organization address new.block.checkb
  831.       organization output
  832.       address output
  833.     }
  834.   if$
  835.   format.edition output
  836.   format.date output
  837.   new.block
  838.   note output
  839.   fin.entry
  840. }
  841.  
  842. FUNCTION {mastersthesis}
  843. { output.bibitem
  844.   format.authors "author" output.check
  845.   after.authors
  846.   format.title "title" output.check
  847.   new.block
  848.   "\btxmastthesis{}" format.thesis.type output.nonnull
  849.   school "school" output.check
  850.   address output
  851.   format.date "year" output.check
  852.   new.block
  853.   note output
  854.   fin.entry
  855. }
  856.  
  857. FUNCTION {misc}
  858. { output.bibitem
  859.   format.authors output
  860.   title howpublished new.block.checkc
  861.   format.title output
  862.   howpublished new.block.checka
  863.   howpublished output
  864.   format.date output
  865.   new.block
  866.   note output
  867.   fin.entry
  868.   empty.misc.check
  869. }
  870.  
  871. FUNCTION {phdthesis}
  872. { output.bibitem
  873.   format.authors "author" output.check
  874.   after.authors
  875.   format.btitle "title" output.check
  876.   new.block
  877.   "\btxphdthesis{}" format.thesis.type output.nonnull
  878.   school "school" output.check
  879.   address output
  880.   format.date "year" output.check
  881.   new.block
  882.   note output
  883.   fin.entry
  884. }
  885.  
  886. FUNCTION {proceedings}
  887. { output.bibitem
  888.   editor empty$
  889.     { organization smallcaps output }
  890.     { format.editors output.nonnull }
  891.   if$
  892.   after.authors
  893.   format.btitle "title" output.check
  894.   format.bvolume output
  895.   format.number.series output
  896.   address empty$
  897.     { editor empty$
  898.         { publisher new.sentence.checka }
  899.         { organization publisher new.sentence.checkb
  900.           organization output
  901.         }
  902.       if$
  903.       publisher output
  904.       format.date "year" output.check
  905.     }
  906.     { address output.nonnull
  907.       format.date "year" output.check
  908.       new.sentence
  909.       editor empty$
  910.         'skip$
  911.         { organization output }
  912.       if$
  913.       publisher output
  914.     }
  915.   if$
  916.   new.block
  917.   note output
  918.   fin.entry
  919. }
  920.  
  921. FUNCTION {techreport}
  922. { output.bibitem
  923.   format.authors "author" output.check
  924.   after.authors
  925.   format.title "title" output.check
  926.   new.block
  927.   format.tr.number output.nonnull
  928.   institution "institution" output.check
  929.   address output
  930.   format.date "year" output.check
  931.   new.block
  932.   note output
  933.   fin.entry
  934. }
  935.  
  936. FUNCTION {unpublished}
  937. { output.bibitem
  938.   format.authors "author" output.check
  939.   after.authors
  940.   format.title "title" output.check
  941.   new.block
  942.   note "note" output.check
  943.   format.date output
  944.   fin.entry
  945. }
  946.  
  947. FUNCTION {default.type} { misc }
  948.  
  949. MACRO {jan} {"\btxmonjanshort{.}"}
  950.  
  951. MACRO {feb} {"\btxmonfebshort{.}"}
  952.  
  953. MACRO {mar} {"\btxmonmarshort{.}"}
  954.  
  955. MACRO {apr} {"\btxmonaprshort{.}"}
  956.  
  957. MACRO {may} {"\btxmonmayshort{.}"}
  958.  
  959. MACRO {jun} {"\btxmonjunshort{.}"}
  960.  
  961. MACRO {jul} {"\btxmonjulshort{.}"}
  962.  
  963. MACRO {aug} {"\btxmonaugshort{.}"}
  964.  
  965. MACRO {sep} {"\btxmonsepshort{.}"}
  966.  
  967. MACRO {oct} {"\btxmonoctshort{.}"}
  968.  
  969. MACRO {nov} {"\btxmonnovshort{.}"}
  970.  
  971. MACRO {dec} {"\btxmondecshort{.}"}
  972.  
  973. MACRO {acmcs} {"ACM Comput. Surv."}
  974.  
  975. MACRO {acta} {"Acta Inf."}
  976.  
  977. MACRO {cacm} {"Commun. ACM"}
  978.  
  979. MACRO {ibmjrd} {"IBM J. Res. Dev."}
  980.  
  981. MACRO {ibmsj} {"IBM Syst.~J."}
  982.  
  983. MACRO {ieeese} {"IEEE Trans. Softw. Eng."}
  984.  
  985. MACRO {ieeetc} {"IEEE Trans. Comput."}
  986.  
  987. MACRO {ieeetcad}
  988.  {"IEEE Trans. Comput.-Aided Design Integrated Circuits"}
  989.  
  990. MACRO {ipl} {"Inf. Process. Lett."}
  991.  
  992. MACRO {jacm} {"J.~ACM"}
  993.  
  994. MACRO {jcss} {"J.~Comput. Syst. Sci."}
  995.  
  996. MACRO {scp} {"Sci. Comput. Programming"}
  997.  
  998. MACRO {sicomp} {"SIAM J. Comput."}
  999.  
  1000. MACRO {tocs} {"ACM Trans. Comput. Syst."}
  1001.  
  1002. MACRO {tods} {"ACM Trans. Database Syst."}
  1003.  
  1004. MACRO {tog} {"ACM Trans. Gr."}
  1005.  
  1006. MACRO {toms} {"ACM Trans. Math. Softw."}
  1007.  
  1008. MACRO {toois} {"ACM Trans. Office Inf. Syst."}
  1009.  
  1010. MACRO {toplas} {"ACM Trans. Prog. Lang. Syst."}
  1011.  
  1012. MACRO {tcs} {"Theoretical Comput. Sci."}
  1013.  
  1014. READ
  1015.  
  1016. FUNCTION {sortify}
  1017. { purify$
  1018.   "l" change.case$
  1019. }
  1020.  
  1021. INTEGERS { len }
  1022.  
  1023. FUNCTION {chop.word}
  1024. { 's :=
  1025.   'len :=
  1026.   s #1 len substring$ =
  1027.     { s len #1 + global.max$ substring$ }
  1028.     's
  1029.   if$
  1030. }
  1031.  
  1032. FUNCTION {sort.format.names}
  1033. { 's :=
  1034.   #1 'nameptr :=
  1035.   ""
  1036.   s num.names$ 'numnames :=
  1037.   numnames 'namesleft :=
  1038.     { namesleft #0 > }
  1039.     { nameptr #1 >
  1040.         { "   " * }
  1041.         'skip$
  1042.       if$
  1043.       s nameptr "{ll{ }}{  f{ }}{vv{ } }{  jj{ }}" format.name$ 't :=
  1044.       nameptr numnames = t "others" = and
  1045.         { "et al" * }
  1046.         { t sortify * }
  1047.       if$
  1048.       nameptr #1 + 'nameptr :=
  1049.       namesleft #1 - 'namesleft :=
  1050.     }
  1051.   while$
  1052. }
  1053.  
  1054. FUNCTION {sort.format.title}
  1055. { 't :=
  1056.   "A " #2
  1057.     "An " #3
  1058.       "The " #4 t chop.word
  1059.     chop.word
  1060.   chop.word
  1061.   sortify
  1062.   #1 global.max$ substring$
  1063. }
  1064.  
  1065. FUNCTION {author.sort}
  1066. { author empty$
  1067.     { key empty$
  1068.         { "to sort, need author or key in " cite$ * warning$
  1069.           ""
  1070.         }
  1071.         { key sortify }
  1072.       if$
  1073.     }
  1074.     { author sort.format.names }
  1075.   if$
  1076. }
  1077.  
  1078. FUNCTION {author.editor.sort}
  1079. { author empty$
  1080.     { editor empty$
  1081.         { key empty$
  1082.             { "to sort, need author, editor, or key in " cite$ * warning$
  1083.               ""
  1084.             }
  1085.             { key sortify }
  1086.           if$
  1087.         }
  1088.         { editor sort.format.names }
  1089.       if$
  1090.     }
  1091.     { author sort.format.names }
  1092.   if$
  1093. }
  1094.  
  1095. FUNCTION {author.organization.sort}
  1096. { author empty$
  1097.     { organization empty$
  1098.         { key empty$
  1099.             { "to sort, need author, organization, or key in " cite$ * warning$
  1100.               ""
  1101.             }
  1102.             { key sortify }
  1103.           if$
  1104.         }
  1105.         { "The " #4 organization chop.word sortify }
  1106.       if$
  1107.     }
  1108.     { author sort.format.names }
  1109.   if$
  1110. }
  1111.  
  1112. FUNCTION {editor.organization.sort}
  1113. { editor empty$
  1114.     { organization empty$
  1115.         { key empty$
  1116.             { "to sort, need editor, organization, or key in " cite$ * warning$
  1117.               ""
  1118.             }
  1119.             { key sortify }
  1120.           if$
  1121.         }
  1122.         { "The " #4 organization chop.word sortify }
  1123.       if$
  1124.     }
  1125.     { editor sort.format.names }
  1126.   if$
  1127. }
  1128.  
  1129. FUNCTION {presort}
  1130. { type$ "book" =
  1131.   type$ "inbook" =
  1132.   or
  1133.     'author.editor.sort
  1134.     { type$ "proceedings" =
  1135.         'editor.organization.sort
  1136.         { type$ "manual" =
  1137.             'author.organization.sort
  1138.             'author.sort
  1139.           if$
  1140.         }
  1141.       if$
  1142.     }
  1143.   if$
  1144.   "    "
  1145.   *
  1146.   year field.or.null sortify
  1147.   *
  1148.   "    "
  1149.   *
  1150.   title field.or.null
  1151.   sort.format.title
  1152.   *
  1153.   #1 entry.max$ substring$
  1154.   'sort.key$ :=
  1155. }
  1156.  
  1157. ITERATE {presort}
  1158.  
  1159. SORT
  1160.  
  1161. STRINGS { longest.label }
  1162.  
  1163. INTEGERS { number.label longest.label.width }
  1164.  
  1165. FUNCTION {initialize.longest.label}
  1166. { "" 'longest.label :=
  1167.   #1 'number.label :=
  1168.   #0 'longest.label.width :=
  1169. }
  1170.  
  1171. FUNCTION {longest.label.pass}
  1172. { number.label int.to.str$ 'label :=
  1173.   number.label #1 + 'number.label :=
  1174.   label width$ longest.label.width >
  1175.     { label 'longest.label :=
  1176.       label width$ 'longest.label.width :=
  1177.     }
  1178.     'skip$
  1179.   if$
  1180. }
  1181.  
  1182. EXECUTE {initialize.longest.label}
  1183.  
  1184. ITERATE {longest.label.pass}
  1185.  
  1186. FUNCTION {begin.bib}
  1187. { preamble$ empty$
  1188.     'skip$
  1189.     { preamble$ write$ newline$ }
  1190.   if$
  1191.   "\begin{thebibliography}{"  longest.label  * "}" * write$ newline$
  1192. }
  1193.  
  1194. EXECUTE {begin.bib}
  1195.  
  1196. EXECUTE {init.state.consts}
  1197.  
  1198. ITERATE {call.type$}
  1199.  
  1200. FUNCTION {end.bib}
  1201. { newline$
  1202.   "\end{thebibliography}" write$ newline$
  1203. }
  1204.  
  1205. EXECUTE {end.bib}
  1206.